*================================================================
      * RPGUPS
      *
      * THIS IS A SAMPLE RPG/400 (RPG III) PROGRAM WHICH DEMONSTRATES
      * THE CALLING OF THE MAXICODE ENCODER.  THERE IS NO DOUBT
      * ABOUT IT; I AM THE WORLD'S WORST RPG PROGRAMMER.  HOPEFULLY
      * THIS IS GOOD ENOUGH TO DEMONSTRATE THE BASICS OF WHAT
      * NEEDS TO BE DONE.
      *
      * THIS DEMO IS FOR ENCODER VERSION 2.1.1 AND LATER
      *
      *================================================================
     H
     FMAXICODEO   E                    PRINTER
      *================================================================
     I              '339010000'           C         $ZIP
     I              '1Z34567890'          C         $TRAC
      *================================================================
     IOMAXI       DS
     I                                        1  30 MAX01
     I                                       31  60 MAX02
     I                                       61  90 MAX03
     I                                       91 120 MAX04
     I                                      121 150 MAX05
     I                                      151 180 MAX06
     I                                      181 210 MAX07
     I                                      211 240 MAX08
     I                                      241 270 MAX09
     I                                      271 300 MAX10
     I                                      301 330 MAX11
     I                                      331 360 MAX12
     I                                      361 390 MAX13
     I                                      391 420 MAX14
     I                                      421 450 MAX15
     I                                      451 480 MAX16
     I                                      481 510 MAX17
     I                                      511 513 ERROR
     IIMAXI       DS
     I                                        1   9 #PCODE
     I                                       10  120#CCODE
     I                                       13  150#SERVC
     I                                       16  25 #TRACK
     I                                       26  31 #SHIP#
     I                                       32  340#JDATE
     I                                       35  64 #SHPID
     I                                       65  680#PID
     I                                       69  720#COUNT
     I                                       73  770#WEGHT
     I                                       78  78 #ADDVL
     I                                       79 113 #SHPTO
     I                                      114 133 #CITY
     I                                      134 148 #FILL1
     I                                      149 150 #STATE
     I                                      151 151 #MCTRL
      *******************************
      *  CALL MAXICODE ENCODER
      *******************************
     C                     EXSR S001
      *******************************
      *  PRINT MAXICODE
      *******************************
     C                     EXSR S002
      *******************************
      *  END OF PROGRAM
      *******************************
     C                     SETON                     LR
      *========================================================
      *  S001 - CALL THE MAXICODE ENCODER
      *========================================================
     C           S001      BEGSR
      *
      * INITIALIZE OUR INPUT RECORD
      *
     C                     CLEARIMAXI
     C                     MOVEL$ZIP      #PCODE
     C                     MOVE 840       #CCODE
     C                     MOVE 1         #SERVC
     C                     MOVEL$TRAC     #TRACK
     C                     MOVEL'102562'  #SHIP#
     C                     MOVE 34        #JDATE
     C                     MOVE 1         #PID
     C                     MOVE 1         #COUNT
     C                     MOVE 20        #WEGHT
     C                     MOVEL'Y'       #ADDVL
     C                     MOVEL'FT MYERS'#CITY
     C                     MOVEL'FL'      #STATE
     C                     MOVEL'0'       #MCTRL
      *
      *  HERE IS WHERE THE MAXICODE ENCODER IS CALLED; IT IS
      *  AN EXTERNAL ILE PROGRAM
      *
     C                     CALL 'MAXUPSN'
     C                     PARM           IMAXI
     C                     PARM           OMAXI
     C                     ENDSR
      *========================================================
      *  S002 - PRINT THE MAXICODE SYMBOL
      *========================================================
     C           S002      BEGSR
     C                     MOVELMAX01     MAXI01
     C                     MOVELMAX02     MAXI02
     C                     MOVELMAX03     MAXI03
     C                     MOVELMAX04     MAXI04
     C                     MOVELMAX05     MAXI05
     C                     MOVELMAX06     MAXI06
     C                     MOVELMAX07     MAXI07
     C                     MOVELMAX08     MAXI08
     C                     MOVELMAX09     MAXI09
     C                     MOVELMAX10     MAXI10
     C                     MOVELMAX11     MAXI11
     C                     MOVELMAX12     MAXI12
     C                     MOVELMAX13     MAXI13
     C                     MOVELMAX14     MAXI14
     C                     MOVELMAX15     MAXI15
     C                     MOVELMAX16     MAXI16
     C                     MOVELMAX17     MAXI17
     C                     WRITEMAXIOUT
     C                     ENDSR